Public Function SendEmail(strMailTo As String, strSubject As String,  _
  strBodyText As String, blnReceipt As Boolean, Optional strAttachment As _
   String, Optional strCCTo As String, Optional strBCCTo As String) As Long
 
'This will return 0 if successfull else error number
    Dim objApp                  As Object
    Dim objMail                 As Object
    Dim objLotusDB              As Object
    Dim objLotusItem            As Object
    Dim arrAttachment()         As String
    Dim strLotusUser            As String
    Dim strLotusDbName          As String
    Dim intAttachLoop           As Integer
 
    DoEvents
 
    On Error GoTo ErrHandler
    Set objApp = CreateObject("Notes.NotesSession")
 
    strLotusUser = objApp.UserName
    strLotusDbName = Left$(strLotusUser, 1) & Right$(strLotusUser, (Len _
     (strLotusUser) - InStr(1, strLotusUser, " "))) & ".nsf"
 
    Set objLotusDB = objApp.GETDATABASE("", strLotusDbName)
 
    If Not objLotusDB.IsOpen Then
        objLotusDB.OPENMAIL
    End If
 
    Set objMail = objLotusDB.CREATEDOCUMENT
    Set objLotusItem = objMail.CREATERICHTEXTITEM("BODY")
 
    With objMail
        .Form = "Memo"
        .sendTo = split(strMailTo, ",")
        If Len(strCCTo) > 0 Then .CopyTo = split(strCCTo, ",")
        If Len(strBCCTo) > 0 Then .BlindCopyTo = split(strBCCTo, ",")
        .Subject = strSubject
        .Body = strBodyText
        .posteddate = Now()
        If blnReceipt Then .ReturnReceipt = "1"
        .SaveMessageOnSend = True
 
        'Attachments
        If Len(strAttachment) > 0 Then
            arrAttachment() = split(strAttachment, ",")
            For intAttachLoop = 0 To UBound(arrAttachment, 1)
                Call objLotusItem.EmbedObject(1454, vbNullString, _
                    arrAttachment(intAttachLoop), "")
            Next intAttachLoop
        End If
 
        .Visible = True
        .Send False
    End With
 
    SendEmail = 0 'Success returned
    
exitSendAttachment:
    Set objLotusDB = Nothing
    Set objLotusItem = Nothing
    Set objApp = Nothing
    Set objMail = Nothing
    Exit Function
 
ErrHandler:
    SendEmail = Err.Number 'Error returned
    GoTo exitSendAttachment
 
End Function