Thanks Manny,
I will try this out and will let you know if it worked.
Pedro

Hi,

I can suggest some subroutine to automate your Save As task. Before use it note the following:

 1) Put the subroutine into the standard code module.

 2) Go to in VBE menu Tools -> References..., check Microsoft Scripting Runtime if not.

 3) When run the macro a dialog window will open to browse and select a folder which contain the files you want to resave. Afterwards, another dialog window will open to select a folder in which the files to be resaved. You can select the same folder in both dialog windows but this will replace any existing file without prompt you with the new one.

Here's the subroutine:

' ************************* ' ************************ '

Sub ReSaveXlsFiles()

    Dim strTargetFolderPath As String
    Dim strDestinationFolderPath As String
    Dim oFSO As FileSystemObject
    Dim oFolder As Folder
    Dim oFile As File
    Dim oWbk As Workbook
    Dim intCounter As Integer
    Dim strPrompt As String
    Dim strTitle As String
   
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
   
    On Error GoTo ERROR_HANDLER
   
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Target Folder"
       
        If .Show = -1 Then
            strTargetFolderPath = .SelectedItems(1)
           
            With Application.FileDialog(msoFileDialogFolderPicker)
                .Title = "Destination Folder"
               
                If .Show = -1 Then
                    strDestinationFolderPath = .SelectedItems(1)
                   
                    Set oFSO = New FileSystemObject
                    Set oFolder = oFSO.GetFolder( _
                        FolderPath:=strTargetFolderPath)
                   
                    For Each oFile In oFolder.Files
                        With oFile
                            If Right(.Name, 4) = ".xls" Then
                                Set oWbk = Workbooks.Open( _
                                    Filename:=.Path)
                               
                                With oWbk
                                    .SaveAs _
                                        Filename:=strDestinationFolderPath & "\" & .Name, _
                                        FileFormat:=xlExcel8
                                    .Saved = True
                                    .Close
                                End With
                               
                                intCounter = intCounter + 1
                            End If
                        End With
                    Next oFile
                End If
            End With
        End If
    End With
   
EXIT_SUB:
    strPrompt = "Number of resaved file(s): " & intCounter & vbCrLf & _
        "From: " & strTargetFolderPath & vbCrLf & _
        "To: " & strDestinationFolderPath
    strTitle = "Resaved file(s)"
   
    MsgBox Prompt:=strPrompt, Title:=strTitle
   
    Set oWbk = Nothing
    Set oFile = Nothing
    Set oFolder = Nothing
    Set oFSO = Nothing
   
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    Exit Sub
   
ERROR_HANDLER:
    ' Some code for error handling
    Err.Clear
    Resume EXIT_SUB

End Sub

' ************************* ' ************************ '

If there is something else - ask.

Best regards.